COMMENT ⊗   VALID 00005 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	{$NOMAIN	Editor: Statement printing routine Aux routines }
C00031 00003	{ Externally defined routines from elsewhere: }
C00033 00004	(* putStmnt aux routine to handle about half of the statement types *)
C00039 00005	(* putst1: main part *)
C00044 ENDMK
C⊗;
{$NOMAIN	Editor: Statement printing routine Aux routines }

(* definition of record types & global variables used by AL *)

const 

  maxLines = 28;
  maxPPLines = 12;
  maxBpts = 25;
  maxTBpts = 20;	(* max could be exceeded by huge case stmnt *)
  listinglength = 2000;	(* Length of Listingarray *)

type

(* random type declarations for OMSI/SAIL compatibility *)

 ascii = char;
 atext = text;
 byte = 0..255;	

(* Here are all the pointer-type definitions.  Since the various 	*)
(* records reference each other so much, we have to put them all here.	*)

vectorp = ↑vector;
transp = ↑trans;
strngp = ↑strng;
eventp = ↑event;
framep = ↑frame;
statementp = ↑statement;
varidefp = ↑varidef;
nodep = ↑node;
identp = ↑ident;
tokenp = ↑token;
reswordp = ↑resword;
pdbp = ↑pdb;
envheaderp = ↑envheader;
enventryp = ↑enventry;
environp = ↑environment;
cmoncbp = ↑cmoncb;
messagep = ↑message;
linerecp = ↑linerec;


(* datatype definitions *)

datatypes = (pconstype, varitype, svaltype, vectype, rottype, transtype,
	     frametype, eventtype, strngtype, labeltype, proctype, arraytype,
	     reftype, valtype, cmontype, nulltype, undeftype,
	     dimensiontype, mactype, macargtype, freevartype);

scalar = real;
vector = record  refcnt: integer; val: array [1..3] of real end;
trans = record  refcnt: integer; val: array [1..3,1..4] of real end;

cstring = packed array [1..10] of ascii;
c4str = packed array [1..4] of ascii;
c5str = packed array [1..5] of ascii;
c20str = packed array [1..20] of ascii;
linestr = packed array [1..130] of ascii;

strng = record
	  next: strngp;
	  ch: cstring;
	end;

event = record
	  next: eventp;		(* all events are on one big list *)
	  count: integer;
	  waitlist: pdbp;
	end;

frame = record
	  vari: varidefp;	(* back pointer to variable name & info *)
	  calcs: nodep;		(* affixment info *)
	  case ftype: boolean of	(* frame = true, device = false *)
  true:	    (valid: integer; val, fdepr: transp; dcntr: integer; dev: framep);
  false:    (mech: integer; case sdev: boolean of
		true: (sdest: real); false: (tdest,appr,depr: transp));
		(* sdev = true for scalar devices, false for frames *)
	end;


(* statement definitions *)

stmntypes = (progtype, blocktype, coblocktype, endtype, coendtype,
		fortype, iftype, whiletype, untiltype, casetype,
		calltype, returntype,
		printtype, prompttype, pausetype, aborttype, assigntype,
		signaltype, waittype, enabletype, disabletype, cmtype,
		affixtype, unfixtype,
		movetype,jtmovetype,operatetype,opentype,closetype,centertype,
		floattype, stoptype, retrytype,
		requiretype, definetype, macrotype, commenttype, dimdeftype,
		setbasetype, wristtype, saytype, declaretype, emptytype,
		evaltype, armmagictype);
		(* more??? *)

statement = packed record
		next, last: statementp;
		stlab: varidefp;
		exprs: nodep;	(* any expressions used by this statement *)
		nlines: integer;
		bpt,bad: boolean;
		case stype: stmntypes of

    progtype:	    (pcode: statementp; errors: integer);
    blocktype,
    declaretype,
    endtype,
    coendtype:	    (bcode, bparent: statementp; blkid: identp;
			level, numvars: 0..255; variables: varidefp);
    coblocktype:    (threads: nodep; nthreads: integer; cblkid: identp);
    fortype:	    (forvar, initial, step, final: nodep; fbody: statementp);
    whiletype,
    untiltype:	    (cond: nodep; body: statementp);
    iftype:	    (icond: nodep; thn, els: statementp);
		end;



(* auxiliary definitions: variable, etc. *)

varidef = packed record
	    next,dnext: varidefp;
	    name: identp;
	    level: 0..255;	(* environment level *)
	    offset: 0..255;	(* environment offset *)
	    dtype: varidefp;	(* to hold the dimension info *)
	    tbits: 0..15;  (* special type bits: array = 1, proc = 2, ref = 4 & ? *)
	    dbits: 0..15;	(* for use by debugger/interpreter *)
	    case vtype: datatypes of
  arraytype:  (a: nodep);
  proctype:   (p: nodep);
  labeltype,
  cmontype:   (s: statementp);
  mactype:    (mdef: statementp);
  macargtype: (marg: tokenp);
  pconstype:  (c: nodep);
  dimensiontype: (dim: nodep);
	  end;



(* definition of the ubiquitous NODE record *)

nodetypes = (exprnode, leafnode, listnode, clistnode, colistnode, forvalnode,
		deprnode, viaptnode, apprnode, destnode, byptnode, durnode,
		sfacnode, wobblenode, swtnode, nullingnode, wristnode, cwnode,
		arrivalnode, departingnode,
		ffnode, forcenode, stiffnode, gathernode, cmonnode, errornode,
		calcnode, arraydefnode, bnddefnode, bndvalnode,
		waitlistnode, procdefnode, tlistnode, dimnode, commentnode,
		linearnode, elbownode, shouldernode, flipnode, wrtnode,
		loadnode,velocitynode);

exprtypes =  (	svalop,					(* scalar operators *)
		sltop, sleop, seqop, sgeop, sgtop, sneop,	(* relations *)
		notop, orop, xorop, andop, eqvop,		(* logical *)
		saddop, ssubop, smulop, sdivop, snegop, sabsop, (* scalar ops *)
		sexpop, maxop, minop, intop, idivop, modop,
		sqrtop, logop, expop, timeop,			(* functions *)
		sinop, cosop, tanop, asinop, acosop, atan2op,	(* trig *)
		vdotop, vmagnop, tmagnop,
		vecop,					(* vector operators *)
		vmakeop, unitvop, vaddop, vsubop, crossvop, vnegop,
		svmulop, vsmulop, vsdivop, tvmulop, wrtop,
		tposop, taxisop,
		transop,				(* trans operators *)
		tmakeop, torientop, ttmulop, tvaddop, tvsubop, tinvrtop,
		vsaxwrop, constrop, ftofop, deproachop, fmakeop, vmkfrcop,
		ioop,					(* i/o operators *)
		queryop, inscalarop,
		specop,					(* special operators *)
		arefop, callop, grinchop, macroop, vmop, adcop, dacop, jointop,
		badop,
		addop, subop, negop, mulop, divop, absop); (* for parsing *)

leaftypes = pconstype..strngtype;

reltypes = sltop..sgtop;
forcetypes = (force,absforce,torque,abstorque,angvelocity);

node = record
	next: nodep;
	case ntype: nodetypes of
    exprnode:	(op: exprtypes; arg1, arg2, arg3: nodep; elength: integer);
    leafnode:	(case ltype: leaftypes of
	varitype:  (vari: varidefp; vid: identp);
	pconstype: (cname: varidefp; pcval: nodep);
	svaltype:  (s: scalar; wid: integer);
	vectype:   (v: vectorp);
	transtype: (t: transp);
	strngtype: (length: integer; str: strngp) ); (* also used by commentnodes *)
    listnode:	(lval: nodep);
    clistnode:	(cval: integer; stmnt: statementp; clast: nodep);
    colistnode:	(prev: nodep; cstmnt: statementp);
    forvalnode:	(fvar: enventryp; fstep: scalar);
    arraydefnode: (numdims: 1..10; bounds: nodep; combnds: boolean);
    bnddefnode:	(lower, upper: nodep);
    bndvalnode:	(lb, ub, mult: integer);
    procdefnode:(ptype: datatypes; level: 0..255;
		    pname, paramlist: varidefp; body: statementp);
    tlistnode:	(tok: tokenp);
	end;



(* records for parser: ident, token, resword *)

ident = record
	    next: identp;
	    length: integer;
	    name: strngp;
	    predefined: varidefp;
	  end;


tokentypes = (reswdtype, identtype, constype, comnttype, delimtype, labeldeftype,
		macpartype);

constypes = svaltype..strngtype;

reswdtypes = (stmnttype, filtype, clsetype, decltype, optype, edittype);

filtypes = (abouttype,alongtype,attype,bytype,defertype,dotype,elsetype,
		errmodestype,fromtype,handtype,intype,nonrigidlytype,rigidlytype,
		sourcefiletype,steptype,thentype,totype,untltype,viatype,
		withtype,worldtype,zeroedtype,oftype,wheretype,nowaittype,
		ontype,offtype,ppsizetype,collecttype,alltype,lextype,
		notype,righttype,lefttype,uptype,downtype,motiontype);

clsetypes = (approachtype,arrivaltype,departuretype,departingtype,durationtype,
		errortype,forcetype,forceframetype,forcewristtype,gathertype,
		nildeproachtype,nullingtype,stiffnesstype,
		torquetype,velocitytype,wobbletype,
		cwtype,ccwtype,stopwaittimetype,angularvelocitytype,
		respecttype,elbowtype,shouldertype,fliptype,lineartype,
		jointspacetype,loadtype);

edittypes = (getcmd,savecmd,insertcmd,renamecmd,startcmd,gocmd,proceedcmd,
		stepcmd,sstepcmd,nstepcmd,gstepcmd,executecmd,setcmd,tracecmd,
		breakcmd,unbreakcmd,tbreakcmd,definecmd,markcmd,unmarkcmd,
		popcmd,atcmd,calibratecmd);

token = record
	  next: tokenp;
	  case ttype: tokentypes of
constype:   (cons: nodep);
comnttype:  (len: integer; str: strngp);
delimtype:  (ch: ascii);
reswdtype:  (case rtype: reswdtypes of
	stmnttype: (stmnt: stmntypes);
	filtype:   (filler: filtypes);
	clsetype:  (clause: clsetypes);
	decltype:  (decl: datatypes);
	optype:	   (op: exprtypes);
	edittype:  (ed: edittypes) );
identtype:  (id: identp);
labeldeftype: (lab: varidefp);
macpartype: (mpar: varidefp);
	end;


resword = record
	  next: reswordp;
	  length: integer;
	  name: strngp;
	  case rtype: reswdtypes of
	stmnttype:  (stmnt: stmntypes);
	filtype:    (filler: filtypes);
	clsetype:   (clause: clsetypes);
	decltype:   (decl: datatypes);
	optype:	    (op: exprtypes);
	edittype:  (ed: edittypes);
	  end;



(* process descriptor blocks & environment record definitions *)

queuetypes = (nullqueue,nowrunning,runqueue,inputqueue,eventqueue,sleepqueue,
		forcewait,devicewait,joinwait,proccall);

pdb = packed record
	nextpdb,next: pdbp;	(* for list of all/active pdb's *)
	level: 0..255;		(* lexical level *)
	mode: 0..255;		(* expression/statement/sub-statement *)
	priority: 0..255;	(* probably never greater than 3? *)
	status: queuetypes;	(* what are we doing *)
	env: envheaderp;
	spc: statementp;	(* current statement *)
	epc: nodep;		(* current expression (if any) *)
	sp: nodep;		(* intermediate value stack *)
	cm: cmoncbp;		(* if we're a cmon point to our definition *)
	mech: framep;		(* current device being used *)
	linenum: integer;	(* used by editor/debugger *)
	 case procp: boolean of	(* true if we're a procedure *)
true:  (opdb: pdbp;		(* pdb to restore when procedure exits *)
	pdef: nodep);		(* procedure definition node *)
false: (evt: eventp;		(* event to signal when process goes away *)
	sdef: statementp);	(* first statement where process was defined *)
      end;


envheader = packed record
	      parent: envheaderp;
	      env: array [0..4] of environp;
	      varcnt: 0..255;		(* # of variables in use ??? *)
		case procp: boolean of  (* true if we're a procedure *)
	true: (proc: nodep);
	false:(block: statementp);
	    end;

enventry = record
	    case etype: datatypes of
  svaltype:  (s: scalar);
  vectype:   (v: vectorp);
  transtype: (t: transp);
  frametype: (f: framep);
  eventtype: (evt: eventp);
  strngtype: (length: integer; str: strngp);
  cmontype:  (c: cmoncbp);
  proctype:  (p: nodep; penv: envheaderp);
  reftype:   (r: enventryp);
  arraytype: (a: envheaderp; bnds: nodep);
	   end;


environment = record
		next: environp;
		vals: array [0..9] of enventryp;
	      end;


cmoncb = record
	   running, enabled: boolean;		(* cmon's status *)
	   cmon: statementp;
	   pdb: pdbp;
	   evt: eventp;
	   fbits: integer;			(* bits for force sensing *)
	   oldcmon: cmoncbp;			(* for debugger *)
	 end;



(* definition of AL-ARM messages *)

msgtypes = (initarmscmd,calibcmd,killarmscmd,wherecmd,
	    abortcmd,stopcmd,movehdrcmd,movesegcmd,
	    centercmd,operatecmd,movedonecmd,signalcmd,
	    setccmd,forcesigcmd,forceoffcmd,biasoncmd,biasoffcmd,setstiffcmd,
	    zerowristcmd,wristcmd,gathercmd,getgathercmd,readadccmd,writedaccmd,
	    errorcmd,floatcmd,setloadcmd,
	    armmagiccmd,realcmd,vectorcmd,transcmd);

errortypes = (noerror,noarmsol,timerr,durerr,toolong,featna,
	      unkmess,srvdead,adcdead,nozind,exjtfc,paslim,nopower,badpot,devbusy,
	      baddev,timout,panicb,nocart,cbound,badparm);

message = record
	   cmd: msgtypes;
	   ok: boolean;
	   case integer of
	1:   (dev, bits, n: integer;
(*	     (dev, bits, n, evt: integer;	(* for arm code version *)
	      evt: eventp;
	      dur: real;
	      case integer of
		1: (v1,v2,v3: real);
		2: (sfac,wobble,pos: real);
		3: (val,angle,mag: real);
		4: (max,min: real);
		5: (error: errortypes));
	2:   (fv1,fv2,fv3,mv1,mv2,mv3: real);	(* may never use these... *)
	3:   (t: array [1..6] of real);
	  end;

interr = record
         case integer of
           0: (i: integer);
	   1: (err,foo: errortypes);
	 end;



(* print related records: *)

cursorp = record
	  cline,ind: integer;
	  case stmntp: boolean of
  true:    (st: statementp);
  false:   (nd: nodep);
	 end;

linerec = record
	next: linerecp;
	start,length: integer
       end;

listingarray = packed array [0..listinglength] of ascii;



(* global variables *)

var
	(* from EDIT *)
    listing: listingarray;  (* first 150 chars are used by expression editor *)
			    (* next 40 by header & trailer lines *)
{*} cursorStack: array [1..15] of cursorp;	{These are BIG records! }
    lbuf: array [1..160] of ascii;
    ppBuf: array [1..100] of ascii;
    lines: array [1..maxLines] of linerecp; (* what's on the screen + some *)
    ppLines: array [1..maxPPLines] of linerecp;	(* for page printer *)
    marks: array [1..20] of integer;
    reswords: array [0..26] of reswordp;
    idents: array [0..26] of identp;
    macrostack: array [1..10] of tokenp;
    curmacstack: array [1..10] of varidefp;
    screenheight,dispHeight: integer;
    ppBufp,oppBufp,ppOffset,ppSize,nmarks: integer;
    lbufp,cursor,ocur,cursorLine,fieldnum,lineNum,findLine,pcLine: integer;
    firstDline,topDline,botDline,firstLine,lastLine,curLine: integer;
    freeLines,oldLines: linerecp;
    sysVars: varidefp;
    dProg: statementp;
    curBlock, newDeclarations, findStmnt: statementp;
    macrodepth: integer;
    filedepth, errCount, sCursor: integer;
    curChar, maxChar, curFLine, curPage: integer;
    nodim, distancedim, timedim, angledim,
      forcedim, torquedim, veldim, angveldim: varidefp;
    fvstiffdim, mvstiffdim: nodep;
    pnode: nodep;
    smartTerminal: boolean; (* true = insert/delete, false = redraw line *)
    setUp,setExpr,setCursor,dontPrint,outFilep,collect,fParse,sParse,
      eofError,endOfLine,backup,expandmacros,flushcomments,checkDims,
      shownLine: boolean;
    curtoken: token;
    file1,file2,file3,file4,file5,outFile: atext;

    bpts: array [1..maxBpts] of statementp;	(* debugging crap *)
    tbpts: array [1..maxTBpts] of statementp;
    debugPdbs: array [0..10] of pdbp;
    nbpts,ntbpts,debugLevel: integer;
    eCurInt: pdbp;
    STLevel: integer;		(* set by GO *)
    singleThreadMode,tSingleThreadMode: boolean;

	(* from INTERP *)
    inputLine: array [1..20] of ascii;
    talk: text;			(* for using the speech synthesizer *)
    curInt, activeInts, readQueue, allPdbs: pdbp;
    sysEnv: envheaderp;
    clkQueue: nodep;
    allEvents: eventp;
    etime: integer;		(* used by eval *)
    curtime: integer; (* who knows where this will get updated - an ast? *)
    stime: integer;		(* used for clock queue on 10 *)
    msg: messagep;		(* for AL-ARM interaction *)
    inputp: integer;		(* current offset into inputLine array above *)
    resched, running, escapeI, iSingleThreadMode: boolean;
    msgp: boolean;		(* flag set if any messages pending *)
    inputReady: boolean;

(* various constant pointers *)
    xhat,yhat,zhat,nilvect: vectorp;
    niltrans: transp;
    gpark, rpark: transp;		(* arm park positions *)

(* various device & variable pointers *)
    speedfactor: enventryp;
    garm: framep;

{ Externally defined routines from elsewhere: }

	(* From EAUX1A *)
procedure pushStmnt(s: statementp; indent: integer);		external;
procedure pushNode(n: nodep);					external;

	(* From EPUT *)
procedure putChar(ch: ascii);					external;
procedure put5(ch: c5str; length: integer);			external;
procedure put10(ch: cstring; length: integer);			external;
procedure putLine;						external;
procedure putReal(s: real);					external;
procedure putInt(r: real);					external;
procedure putStrng(length: integer; s: strngp);			external;
procedure putTlist(t: tokenp);					external;
function getExprLength(n: nodep): integer;			external;

	(* From EPUTST *)
procedure putexpr(n: nodep; opp: integer);			external;
procedure newline(indent: integer);				external;
procedure outExpr(n: nodep);					external;

	(* From EROOT *)
procedure ep1putstmnt(s: statementp; indent, plevel: integer);	external;

procedure ePs1Get; external;
procedure ePs1Get; begin end;

(* putStmnt aux routine to handle about half of the statement types *)

procedure putst1(s: statementp; indent, plevel: integer; var l: integer); external;
procedure putst1;
 var i: integer; n: nodep; st: statementp; b: boolean;

(* Aux routine: putVars *)

 procedure putvars(vari: varidefp; indent: integer; b: boolean);
  var vtbits,ovtbits,i: integer; n: nodep; vdt: datatypes; vdim: varidefp;
  begin
  vdt := nulltype;
  ovtbits := 0;
  vdim := nil;
  i := 1;
  while vari <> nil do			(* print out the variable defs *)
   with vari↑ do
    begin
    if (name <> nil) and ((vtype <> dimensiontype) and (vtype <> mactype)) then
     begin
     if (vtype <> vdt) or (tbits <> ovtbits) or (dtype <> vdim) then
       begin
       if (vdt <> nulltype) and (vdt <> proctype) then putchar(';');
       if b then newline(indent)
(*	else if lbufp > 60 then
	 begin 
	 newline(indent);
	 if setCursor and (curLine = cursorLine) then fieldNum := i;
	 end
*)	else putchar(' ');
       vdt := vtype;
       vtbits := tbits;
       ovtbits := tbits;
       vdim := dtype;
       if vtbits >= 4 then
	 begin put10('reference ',10); vtbits := vtbits - 4 end
	else if not b then put10('value     ',6);
       if vdim <> nil then
	begin
	with vdim↑.name↑ do putStrng(length,name);	(* print dimension type *)
	putchar(' ');
	end;
       case vdt of
svaltype:  put10('scalar    ',7);
vectype:   put10('vector    ',7);
rottype:   put5('rot  ',4);
transtype: put10('trans     ',6);
frametype: put10('frame     ',6);
eventtype: put10('event     ',6);
strngtype: put10('string    ',7);
labeltype: put10('label     ',6);
cmontype:  vdt := nulltype;
undeftype: begin put10('(* undefin',10); put10('ed! *)    ',7); end;
otherwise {do nothing};
	end;
       if vtbits = 1 then put10('array     ',6)
	else if vtbits = 2 then put10('procedure ',10);
       end
      else put5(',    ',2);
     if name <> nil then putStrng(name↑.length,name↑.name)
      else begin put10('(* noname ',10); put5('*)   ',2); end;
     if odd(vtbits) and (a <> nil) then
       begin
       if not a↑.combnds then
	begin		  (* print out the array bounds *)
	putchar('[');
	n := a↑.bounds;
	while n <> nil do
	 begin
	 outExpr(n↑.lower);
	 putchar(':');
	 outExpr(n↑.upper);
	 n := n↑.next;
	 if n <> nil then putchar(',');
	 end;
	putchar(']');
	end
       end
      else if (vtbits = 2) and (p <> nil) then
       begin
       if setCursor and (curLine <= cursorLine) and 
			(cursorLine < curLine + p↑.body↑.nlines + 1) then
	 begin
	 pushNode(p);
	 cursorStack[cursor].cline := curLine;
	 end;
       if p↑.paramlist <> nil then
	 begin
	 putchar('(');
	 putvars(p↑.paramlist,lbufp,false);
	 putchar(')');
	 end;
       putchar(';');
       ep1PutStmnt(p↑.body,indent+2,plevel);
       putchar(';');
       vdt := nulltype;
       ovtbits := 0;
       end;
     end;
    if b then
      if vtbits = 2 then vari := nil	(* only one procedure per decl stmnt *)
       else vari := vari↑.dnext		(* declare statement *)
     else vari := vari↑.next;		(* procedure parameter list *)
    i := i + 1;
    end;
  if b and (vdt <> nulltype) then putchar(';');
  end;

(* putst1: main part *)

begin
with s↑ do 
    case stype of
progtype:	begin
		l := 1;
		putChar(' ');
		ep1PutStmnt(pcode,1,plevel+1);
		putLine;			(* put out last line *)
		end;
blocktype:	begin
		if curLine = 0 then
		  begin
		  curLine := 1;
		  cursorStack[2].cline := 1;
		  end;
		put10('begin     ',6);
		if blkid <> nil then
		  begin putChar('"');
			putStrng(blkid↑.length,blkid↑.name);
			putChar('"') end;
		if plevel = 1 then
		  begin
		  newline(indent+2);
		  put5('...  ',3);
		  st := bcode;
		  while st↑.stype <> endtype do	st := st↑.next;	(* find end *)
		  ep1PutStmnt(st,indent,plevel);		(* and print it *)
		  end
		 else
		  begin
		  st := bcode;
		  repeat		(* print statements in block *)
		   ep1PutStmnt(st,indent,plevel);
		   if (st↑.stype <> commenttype) and
		      (st↑.stype <> endtype) and
		      (st↑.stype <> declaretype) then putchar(';');
		   st := st↑.next;
		  until st = nil;
		  end;
		end;
coendtype,
endtype:	begin
		if stype = endtype then put5('end  ',4)
		 else put10('coend     ',6);
		if blkid <> nil then
		  begin putChar('"');
			putStrng(blkid↑.length,blkid↑.name);
			putchar('"') end;
		end;
declaretype:	begin
		putvars(variables,indent,true);
		end;
coblocktype:	begin
		put10('cobegin   ',8);
		if cblkid <> nil then
		  begin putChar('"');
			putStrng(cblkid↑.length,cblkid↑.name);
			putchar('"') end;
		if plevel = 1 then
		  begin
		  newline(indent+2);
		  put5('...  ',3);
		  end
		 else
		  begin
		  n := threads;
		  while n <> nil do	(* print out the statements in block *)
		   begin
		   if setCursor then
		    if (curLine < cursorLine) and
		       (cursorLine <= curLine + n↑.cstmnt↑.nlines) then
		      pushNode(n);
		   ep1PutStmnt(n↑.cstmnt,indent+1,plevel);
		   if n↑.cstmnt↑.stype <> commenttype then putchar(';');
		   n := n↑.next;
		   end;
		  end;
		ep1PutStmnt(threads↑.stmnt↑.next,indent,plevel); (* print COEND *)
		end;
fortype:	begin
		put5('for  ',4);
		outExpr(forvar);
		put5(' :=  ',4);
		outExpr(initial);
		put10(' step     ',6);
		outExpr(step);
		put10(' until    ',7);
		outExpr(final);
		put5(' do  ',3);
		ep1PutStmnt(fbody,indent+2,plevel);
		end;
iftype:		begin
		put5('if   ',3);
		outExpr(icond);
		put5(' then',5);
		ep1PutStmnt(thn,indent+2,plevel);
		if els <> nil then
		  begin
		  newline(indent+1);
		  put5('else ',4);
		  if setCursor and (cursorLine = curLine) then fieldNum := 2;
		  ep1PutStmnt(els,indent+2,plevel);
		  end
		end;
whiletype:	begin
		put10('while     ',6);
		outExpr(cond);
		put5(' do  ',3);
		ep1PutStmnt(body,indent+2,plevel);
		end;
(* more??? *)
otherwise	begin put10('Oh no!  1 ',10); put10('Bad ovlay!',10); end;
     end;
end;